Micro Machines v4

[BarryB]

INNO Setup is a very competant install system, script based so you can modify things as needed, if you've never used INNO it would be best to download it and read the help file!

Anyway, I installed the game and patched it to 1.01 then created an INNO script for you to try:

[Setup]
AppName=Micromachines V4
AppVerName=Micromachines V4
DefaultDirName={pf}\Codemasters\MicroMachines V4\
DefaultGroupName=Codemasters
DisableProgramGroupPage=yes
OutputBaseFilename=setup
Compression=lzma
CompressionThreads=auto
DiskSpanning=yes
SlicesPerDisk=1
DiskSliceSize=736000000
SolidCompression=yes

[Files]
Source: "C:\Program Files\Codemasters\MicroMachines V4\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs

[Registry]
Root: HKLM; Subkey: "SOFTWARE\Codemasters"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Codemasters\MicroMachines V4"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Codemasters\MicroMachines V4\1.00.0000"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Codemasters\MicroMachines V4\1.01.0000"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Codemasters\MMV4"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Codemasters\MMV4\1.00.0000"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Codemasters\MMV4\1.00.0000"; ValueName: "installpathname"; ValueType: String; ValueData: "{app}"; Flags: uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Codemasters\MMV4\1.00.0000"; ValueName: "installstatus"; ValueType: String; ValueData: "2"; Flags: uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Codemasters\MMV4\1.00.0000"; ValueName: "Language"; ValueType: String; ValueData: "0"; Flags: uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Codemasters\MMV4\1.00.0000"; ValueName: "uninstallpathname"; ValueType: String; ValueData: "{app}\unins000.exe"; Flags: uninsdeletekey
Root: HKLM; Subkey: "SOFTWARE\Codemasters\MMV4\1.00.0000"; ValueName: "Patch"; ValueType: String; ValueData: "RETV1"; Flags: uninsdeletekey

[Run]
Filename: "{app}\Launch.exe"; Description: "{cm:LaunchProgram,'MicroMachines V4'}"; Flags: postinstall
Filename: "Wordpad.exe"; Parameters: """{app}\Readme.doc"""; Description: "View Readme File"; Flags: postinstall shellexec

[Icons]
Name: "{group}\MicroMachines V4\Funsta"; Filename: "http://www.funsta.co.uk"; WorkingDir: "{app}"; IconFilename: "{app}\codies.ico"
Name: "{group}\MicroMachines V4\Join Code M"; Filename: "http://www.codemasters.co.uk/codem/joinup.php"; WorkingDir: "{app}"; IconFilename: "{app}\codies.ico"
Name: "{group}\MicroMachines V4\MMV4"; Filename: "http://www.codemasters.co.uk/micromachines"; WorkingDir: "{app}"; IconFilename: "{app}\codies.ico"
Name: "{group}\MicroMachines V4\Play MMV4"; Filename: "{app}\launch.exe"; WorkingDir: "{app}";
Name: "{group}\MicroMachines V4\{cm:UninstallProgram,MicroMachines V4}"; Filename: "{uninstallexe}";
Name: "{userdesktop}\MMV4"; Filename: "{app}\Launch.exe"; Tasks: "desktopicon"; WorkingDir: "{app}";

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}";

To create your new installer follow these instructions:

1. Install INNO Setup:

http://www.jrsoftware.org/download.php/is.exe

Let it associate itself with .iss files!
2. Install the game to the default folder, apply the 1.01 patch. You can also apply the 1.01 crack if you don't want to use your DVD!
3. Paste the above script to a file with an .ISS extension e.g.: MMV4.iss, then save it to a drive/folder with about 1GB free space.
4. Click on the newly saved .ISS file to launch INNO, then click the 'Compile' button to create your 2 CD's!! It will create an OUTPUT folder in the same directory as the .ISS file, this is where the install files are saved!
5. When the compile is finished, open the OUTPUT folder and burn SETUP.EXE and SETUP-1.BIN to CD1 and SETUP-2.BIN to CD2, test burn using 80min/700mb CD-RW's in case of problems!
6. Uninstall the game and then test the new install from your CD's!

That's it!

It took about 10 minutes to create the new installer, this was using a 2.8Ghz Dual Core CPU. You should also be able to uninstall the game via the launch menu like the original did! This installer won't remove your save games or install DirectX, just so you know!

[mondragon]

[Run]
Filename: "{app}\Launch.exe"; Description: "{cm:LaunchProgram,'MicroMachines V4'}"; Flags: postinstall

change to

[Run]
Filename: "{app}\Launch.exe"; Description: "{cm:LaunchProgram,'MicroMachines V4'}"; Flags: postinstall nowait