INNO TROUBLESHOOT - Questions Here

[DiCaPrIo]

Originally Posted by Masquerade

Is there a way to detect the amount of CPU threads / cores there are and do something accordingly?

Eg.

if CPU_THREADS = 6 then
begin
do_stuff
end else begin
do_other_stuff
end;

Asking because some multithreading tools crash when dealing with 6 or 12 threads.

function GetSysCores(): Integer;
var
  WbemLocator, WbemServices, WbemObjectSet, WbemObject: Variant;
begin;
  WbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  WbemServices := WbemLocator.ConnectServer('localhost', 'root\CIMV2');
  WbemObjectSet := WbemServices.ExecQuery('Select NumberOfCores from Win32_Processor');
  WbemObject := WbemObjectSet.ItemIndex(0);
  Result := WbemObject.Properties_.Item('NumberOfCores').Value;
  WbemLocator:=Unassigned;
  WbemServices:=Unassigned;
  WbemObjectSet:=Unassigned;
  WbemObject:=Unassigned;
end;

function GetSysThreads(): Integer;
var
  WbemLocator, WbemServices, WbemObjectSet, WbemObject: Variant;
begin;
  WbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  WbemServices := WbemLocator.ConnectServer('localhost', 'root\CIMV2');
  WbemObjectSet := WbemServices.ExecQuery('Select NumberOfLogicalProcessors from Win32_Processor');
  WbemObject := WbemObjectSet.ItemIndex(0);
  Result := WbemObject.Properties_.Item('NumberOfLogicalProcessors').Value;
  WbemLocator:=Unassigned;
  WbemServices:=Unassigned;
  WbemObjectSet:=Unassigned;
  WbemObject:=Unassigned;
end;

[Masquerade]

DiCaPrIo
So I would put if GetSysCores = 6 in the if loop after calling the function?

[DiCaPrIo]

Originally Posted by Masquerade

DiCaPrIo
So I would put if GetSysCores = 6 in the if loop after calling the function?

procedure InitializeWizard();
var Cores,Threads:Integer;
begin
  Cores:=GetSysCores;
  Threads:=GetSysThreads;
  if Cores = 6 then begin
  //yourcode
  end;
  if Threads = 6 then begin
  //yourcode
  end;
end;

[Cesar82]

Originally Posted by Masquerade

DiCaPrIo
So I would put if GetSysCores = 6 in the if loop after calling the function?

As the function returns an integer value I think I can use it directly without declaring variables.
if GetSysCores = 6 then
begin

end;

The function can also be simplified using variables of type variant so you can get any supported value just by changing the string you want to search for.

function GetSysInfo(const WMIClass, WMIProperty: String): Variant;
var
  WbemLocator, WbemServices, WbemObjectSet, WbemObject: Variant;
begin;
  WbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  WbemServices := WbemLocator.ConnectServer('localhost', 'root\CIMV2');
  WbemObjectSet := WbemServices.ExecQuery('Select ' + WMIProperty + ' from ' + WMIClass);
  if (not VarIsNull(WbemObjectSet)) and (WbemObjectSet.Count > 0) then begin
    WbemObject := WbemObjectSet.ItemIndex(0);
    if not VarIsNull(WbemObject) then
      Result := WbemObject.Properties_.Item(WMIProperty).Value;
  end;
end;

procedure GetFreeMemory(var Free, Total: Extended);
begin
  Total := GetSysInfo('Win32_OperatingSystem', 'TotalVisibleMemorySize');
  Free := GetSysInfo('Win32_OperatingSystem ', 'FreePhysicalMemory');
end;

function CPUCores: Integer;
begin
  Result := GetSysInfo('Win32_Processor', 'NumberOfCores');
end;

function CPUThreads: Integer;
begin
  Result := GetSysInfo('Win32_Processor', 'NumberOfLogicalProcessors');
end;

You can also use the API if you prefer to get Threads.

type
  TSystemInfo = record
    wProcessorArchitecture: Word;
    wReserved: Word;
    dwPageSize: DWORD;
    lpMinimumApplicationAddress: Integer;
    lpMaximumApplicationAddress: Integer;
    dwActiveProcessorMask: DWORD;
    dwNumberOfProcessors: DWORD;
    dwProcessorType: DWORD;
    dwAllocationGranularity: DWORD;
    wProcessorLevel: Integer;
    wProcessorRevision: Word;
  end;

procedure GetSystemInfo(var lpSystemInfo: TSystemInfo);
  external '[email protected] stdcall delayload';

function GetCPUThreads: Integer;
var
  SysInfo: TSystemInfo;
begin
  GetSystemInfo(SysInfo);
  Result := SysInfo.dwNumberOfProcessors;
end;