Dark Crusade - Play all races without installing DoW and WA

[spOOL]

If you want to play multiplayer with all races, but don´t want to waste 4GB of HDD space, copy the content of the code section below into a .bat file. Edit the key markers at the top with your valid CD-keys including dashes. Double klick the file, play, have fun.


@echo off

rem -------------------------------------------------------
set W40KKEY="<put DoW key here>"
set WXPKEY="<put WA key here>"

rem -- export Dark Crusade install key --------------------
regedit.exe /e ~dcexp~ "HKEY_LOCAL_MACHINE\SOFTWARE\THQ\Dawn of War - Dark Crusade"

rem -- extract InstallLocation ----------------------------
rem -- uses 'type' to get rid of Unicode characters -------
for /f "tokens=1,2 delims==" %%i in ('type ~dcexp~') do (
if %%i=="InstallLocation" (
set INSTALLLOC="%%~j\\"
)
)
del ~dcexp~

rem -- write Dawn of War + Winter Assault keys ------------
echo Windows Registry Editor Version 5.00 > ~dcimp~
echo. >> ~dcimp~
echo [HKEY_LOCAL_MACHINE\SOFTWARE\THQ\Dawn Of War] >> ~dcimp~
echo "CDKEY"=%W40KKEY% >> ~dcimp~
echo "CDKEY_WXP"=%WXPKEY% >> ~dcimp~
echo "InstallLocation"=%INSTALLLOC% >> ~dcimp~
echo. >> ~dcimp~
echo [HKEY_LOCAL_MACHINE\SOFTWARE\THQ\Dawn of War - Dark Crusade] >> ~dcimp~
echo "W40KCDKEY"=%W40KKEY% >> ~dcimp~
echo "WXPCDKEY"=%WXPKEY% >> ~dcimp~

regedit.exe /s ~dcimp~
del ~dcimp~
set W40KKEY=
set WXPKEY=

rem -- copy exe files -------------------------------------
set INSTALLLOC=%INSTALLLOC:\\=\%
copy /b /y %INSTALLLOC%\DarkCrusade.exe %INSTALLLOC%\W40k.exe 1> NUL
copy /b /y %INSTALLLOC%\DarkCrusade.exe %INSTALLLOC%\W40kWA.exe 1> NUL
set INSTALLLOC=


rÿche on